Android热修复架构杂谈

/**
 * Signing Jar with Android Keystore
 * @param patchDir patch temple data directory
 * @param variant build.gradle signing configuration 
 * @return true, signing jar success
 */
public static boolean signJar(File patchDir, BaseVariant variant) {
    def config = variant.getBuildType().getSigningConfig()

    def buildTypeName = config.getName()
    if (!buildTypeName.equalsIgnoreCase('release')) {
        return false
    }
    
    def patchFile = new File(patchDir, "patch.jar")
    if (patchFile.exists()) {
        def exec = JavaEnvUtils.getJdkExecutable('jarsigner')
        if ("jarsigner".equals(exec)) {
            throw new RuntimeException("Cannot find JAVA_HOME in environment variables")
        }
    
        def storeFile = config.getStoreFile()
        def storePassword = config.getStorePassword()
        def keyAlias = config.getKeyAlias()
        def keyPassword = config.getKeyPassword()
        
        def signPatchFile = new File(patchDir, "patch_signed.jar")
        copyJarFile(patchFile, signPatchFile)

        def command = "${exec} -tsa http://timestamp.digicert.com -keystore ${storeFile.absolutePath} -storepass ${storePassword} -keypass ${keyPassword} ${signPatchFile.absolutePath} ${keyAlias}"
        def proc = command.execute()
        proc.waitFor()
        if (proc.exitValue() != 0) {
            println "Std Out: ${proc.in.text}"
            println "CommandLine: ${command}"
            throw new RuntimeException(proc.err.text);
        } else {
            println("build signed jar success")
            return true
        }
    } else {
        println("WARNING: PATCH FILE IS NOT EXISTS!!!")
    }
    return false
}

static void copyJarFile(File src, File dest) {
    def input = src.newDataInputStream()
    def output = dest.newDataOutputStream()
    output << input
    input.close()
    output.close()
}